MessagePack/build.gradle

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'jacoco'
apply plugin: 'gitflow-version'

sourceCompatibility = 1.7
group = 'ch.dissem.msgpack'

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.11'
}

test {
    testLogging {
        exceptionFormat = 'full'
    }
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { isRelease && project.getProperties().get("signing.keyId")?.length() > 0 }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'msgpack'
                description 'A simple Java library for handling MessagePack data'
                packaging 'jar'
                url 'https://dissem.ch/msgpack'

                scm {
                    connection 'scm:git:https://git.dissem.ch/chris/MessagePack.git'
                    developerConnection 'scm:git:git@git.dissem.ch:chris/MessagePack.git'
                    url 'https://git.dissem.ch/chris/MessagePack.git'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        name 'Christian Basler'
                        email 'chrigu.meyer@gmail.com'
                    }
                }
            }
        }
    }
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

check.dependsOn jacocoTestReport