Abit/app/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'idea'

ext {
    appName = "Abit"
}
if (project.hasProperty("project.configs")
    && new File(project.property("project.configs") + appName + ".gradle").exists()) {
    apply from: project.property("project.configs") + appName + ".gradle"
}

//noinspection GroovyMissingReturnStatement
android {
    compileSdkVersion 28
    buildToolsVersion "28.0.3"

    signingConfigs {
        release
    }
    defaultConfig {
        applicationId "ch.dissem.apps.${appName.toLowerCase()}"
        minSdkVersion 21
        targetSdkVersion 28
        versionCode 23
        versionName "1.0-rc1"
        multiDexEnabled true
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
    lintOptions {
        abortOnError false
    }
    buildTypes {
        release {
            minifyEnabled false
            shrinkResources false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.release
        }
    }
    packagingOptions {
        exclude 'META-INF/core.kotlin_module'
    }
    testOptions {
        unitTests {
            includeAndroidResources = true
        }
    }
}

//ext.jabitVersion = '2.0.4'
ext.jabitVersion = 'feature-refactoring-SNAPSHOT'
ext.supportVersion = '27.1.1'
dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    implementation "org.jetbrains.anko:anko:$anko_version"

    implementation 'androidx.appcompat:appcompat:1.0.0'
    implementation 'androidx.preference:preference:1.0.0'
    implementation 'androidx.cardview:cardview:1.0.0'
    implementation 'androidx.legacy:legacy-support-v13:1.0.0'
    implementation 'androidx.legacy:legacy-preference-v14:1.0.0'
    implementation 'com.google.android.material:material:1.0.0'
    implementation 'androidx.multidex:multidex:2.0.0'
    implementation 'androidx.core:core-ktx:1.0.0'
    implementation 'androidx.sqlite:sqlite-ktx:2.0.0-rc01'
    implementation 'androidx.fragment:fragment-ktx:1.0.0'

    implementation "ch.dissem.jabit:jabit-core:$jabitVersion"
    implementation "ch.dissem.jabit:jabit-networking:$jabitVersion"
    implementation "ch.dissem.jabit:jabit-extensions:$jabitVersion"
    implementation "ch.dissem.jabit:jabit-wif:$jabitVersion"
    implementation "ch.dissem.jabit:jabit-exports:$jabitVersion"
    implementation "ch.dissem.jabit:jabit-cryptography-spongy:$jabitVersion"
    testImplementation "ch.dissem.jabit:jabit-cryptography-bouncy:$jabitVersion"

    implementation 'org.slf4j:slf4j-android:1.7.25'

    implementation 'com.mikepenz:materialize:1.2.0-rc01@aar'
    implementation('com.mikepenz:materialdrawer:6.1.0-rc01.2@aar') {
        transitive = true
    }
    implementation('com.mikepenz:aboutlibraries:6.2.0-rc01@aar') {
        transitive = true
    }
    implementation "com.mikepenz:iconics-core:3.1.0-rc01@aar"
    implementation "com.mikepenz:iconics-views:3.1.0-rc01@aar"
    implementation 'com.mikepenz:google-material-typeface:3.0.1.2.original@aar'
    implementation 'com.mikepenz:community-material-typeface:2.0.46.1@aar'

    implementation 'com.journeyapps:zxing-android-embedded:3.6.0@aar'
    implementation 'com.google.zxing:core:3.3.3'

    implementation 'com.github.kobakei:MaterialFabSpeedDial:1.2.0'
    implementation 'com.github.deano2390:MaterialShowcaseView:1.2.0@aar'
    implementation 'com.github.angads25:filepicker:1.1.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.0-alpha2'

    implementation "io.reactivex.rxjava2:rxjava:2.2.2"
    implementation "io.reactivex.rxjava2:rxkotlin:2.3.0"
    implementation "io.reactivex.rxjava2:rxandroid:2.1.0"

    testImplementation 'junit:junit:4.12'
    testImplementation 'org.mockito:mockito-core:2.19.0'
    testImplementation 'org.hamcrest:hamcrest-library:1.3'
    testImplementation 'com.nhaarman:mockito-kotlin-kt1.1:1.6.0'
    testImplementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    testImplementation 'org.robolectric:robolectric:3.7.1'
    testImplementation "org.robolectric:shadows-multidex:3.7.1"

    androidTestImplementation "androidx.multidex:multidex:2.0.0"
}

idea.module {
    downloadJavadoc = true
    downloadSources = true
}